Multilevel data: melogit vs logit with clustered standard errors

[Mike Smet]

Hello,

I have some questions regarding (dis)advantages of using melogit vs logit, vce(cluster) vs xtlogit when you have multilevel data. Are there any theoretical (or practical) reasons to prefer one or the other?
I specified some alternatives (see code and results below): in this case the results are pretty robust, but in some other cases, coefficients and standard errors may be quite different according to the specification.

use http://www.stata-press.com/data/r15/bangladesh
eststo clear
* Basic multilevel logit
melogit c_use urban age child* || district:
eststo melogit
* Multilevel logit with clusterd standard errors
melogit c_use urban age child* || district:, vce(cluster district)
eststo melogit_cl
* 'Normal' logit with clustered standard errors 
logit c_use urban age child*, vce(cluster district)
eststo logit_cl
* declare panel data (xtset district)
xtset district
* Random intercepts logit (panel data)
xtlogit c_use urban age child*, re
eststo xtlogit_re
* Fixed intercepts logit (panel data)
xtlogit c_use urban age child*, fe
eststo xtlogit_fe
* Manually created fixed intercepts logit (because vce(cluster) is not possible using xtlogit, fe
logit c_use urban age child* i.district
eststo logit_man_fe
* Manually created fixed intercepts logit with clustered s.e. (because vce(cluster) is not possible using xtlogit, fe
logit c_use urban age child* i.district, vce(cluster district)
eststo logit_man_fe_cl
* consolidate output in 1 table
esttab, mtit keep(urban age child*)

----------------------------------------------------------------------------------------------------------------------------
                      (1)             (2)             (3)             (4)             (5)             (6)             (7)   
                  melogit      melogit_cl        logit_cl      xtlogit_re      xtlogit_fe    logit_man_fe    logit_man_~l   
----------------------------------------------------------------------------------------------------------------------------
c_use                                                                                                                       
urban               0.732***        0.732***        0.797***        0.732***        0.644***        0.662***        0.662***
                   (6.13)          (4.39)          (4.21)          (6.13)          (5.12)          (5.19)          (3.58)   

age               -0.0265***      -0.0265***      -0.0239***      -0.0265***      -0.0266***      -0.0274***      -0.0274***
                  (-3.36)         (-3.70)         (-3.49)         (-3.36)         (-3.31)         (-3.36)         (-3.62)   

child1              1.116***        1.116***        1.067***        1.116***        1.123***        1.154***        1.154***
                   (7.06)          (5.73)          (5.82)          (7.06)          (7.01)          (7.10)          (5.59)   

child2              1.366***        1.366***        1.276***        1.366***        1.359***        1.398***        1.398***
                   (7.82)          (8.13)          (7.51)          (7.82)          (7.69)          (7.79)          (7.91)   

child3              1.344***        1.344***        1.214***        1.344***        1.364***        1.404***        1.404***
                   (7.48)          (6.60)          (6.05)          (7.48)          (7.48)          (7.58)          (6.57)   
----------------------------------------------------------------------------------------------------------------------------
N                    1934            1934            1934            1934            1907            1907            1907   
----------------------------------------------------------------------------------------------------------------------------

t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

Thanks a lot for any comments of valuable suggestions,
Mike

[Theresa Thies]

Hello, I have basically the same question. I did some resarch on the difference between melogit || level2: vs. logit, cluster (level2). I have found a German PDF, where they give an example of children nested in schools:
https://www.google.com/url?sa=t&rct=...xD4usdKYWz5twL

There it basically says on page 76, that melogit vs. logit cluster both estimate correct standard errors, however the coefficients are different in their meaning.

Although the logistic multilevel model does not control for total level 2 variance (e.g., school variance), it estimates student-specific conditional effects within schools. Logistic regression, on the other hand, estimates population-averaged or marginal probabilities that fully incorporate both sources of variance (within and between schools). If anyone had to offer a more detailed answer I would be very interested.