Capitalising first letter of value labels

[Sonnen Blume]

In Stata 14 I can change letter case of variables names in a single click by the following formula:

country

rename *, uppercase

COUNTRY

Is it possible to change the value labels as well:

algeria to Algeria

[Clyde Schechter]

Your post is a bit confusing. -rename *, upper- does not just capitalize the first letter of the variable names. It changes them completely to upper case. If you want to change only the first letter of a value label to upper case, the following code illustrates the approach using the online nlswork data set as an example:

webuse nlswork, clear

label dir
label list racelbl

levelsof race, local(races)

foreach r of local races {
    local lbl: label racelbl `r'
//     local lbl = upper(`"`lbl'"')
    local lbl = upper(substr(`"`lbl'"', 1, 1)) + substr(`"`lbl'"', 2, .)
    label define racelbl    `r'    `"`lbl'"', modify
}

label list racelbl

If what you actually want is to convert the entire label to upper case, then un-comment the commented out -local lbl- command and comment out (or just delete) the one below it.

If you want to do this to all of the value labels in the entire data set, you can get a list of the names of those value labels by running -label dir-, and then pick up the list of names of labels from r(names). Then run the above code inside a loop over those label names.

[daniel klein]

Cylde points in the right direction. His example code, however, assumes that all values are indeed labeled and that all labeled values do indeed appear in the dataset at hand. The labvalch3 command, part of labutil2 (from SSC) offers a canned solution that essentially implements Clydes code. The syntax is very similar to rename, in this case.

labvalch3 * , upper

If you want to change value label names, there is a labelrename command (SJ) but you will need to loop over value label names as Clyde suggests.

Best
Daniel

[Sonnen Blume]

Cylde points in the right direction. His example code, however, assumes that all values are indeed labeled and that all labeled values do indeed appear in the dataset at hand. The labvalch3 command, part of labutil2 (from SSC) offers a canned solution that essentially implements Clydes code. The syntax is very similar to rename, in this case.

labvalch3 * , upper

If you want to change value label names, there is a labelrename command (SJ) but you will need to loop over value label names as Clyde suggests.

Best
Daniel

Thanks Daniel for the wonderful technology. It works fine except that it capitalises all the letters.

[daniel klein]

It works fine except that it capitalises all the letters.

Clyde has pointed this out and already pointed to a solution; with labvalch3 this would be

labvalch3 * , strfcn(upper(substr(`"@"', 1, 1))+substr(`"@"', 2, .))

If you want the first letter of every word capitalized, the syntax is simpler

labvalch3 * , proper

By the way, we prefer full real names here on Statalist.

Best
Daniel

[Sonnen Blume]

Clyde has pointed this out and already pointed to a solution; with labvalch3 this would be

labvalch3 * , strfcn(upper(substr(`"@"', 1, 1))+substr(`"@"', 2, .))

If you want the first letter of every word capitalized, the syntax is simpler

labvalch3 * , proper

By the way, we prefer full real names here on Statalist.

Best
Daniel

Thanks again Daniel. I was able to use

labvalch3 * , upper

as

labvalch3 * , proper

is showing error message.

. labvalch3 * , proper
option proper not allowed

[daniel klein]

Sorry, my bad; I have never released the version of labvalch3 that supports the proper option. You can still use the function as

labvalch3 * , strfcn(proper(`"@"'))

Best
Daniel

[Sonnen Blume]

Sorry, my bad; I have never released the version of labvalch3 that supports the proper option. You can still use the function as

labvalch3 * , strfcn(proper(`"@"'))

Best
Daniel

This one worked! Thanks so much, it made my day.