dot plot question

[Javad Ebrahimzadeh]

Hello
this is my data set

clear
input year str4 quintile cpm
1995 q1 28.2
1995 q2 39
1995 q3 47.1
1995 q4 52
1995 q5 57.4
2000 q1 42.7
2000 q2 50
2000 q3 54.3
2000 q4 58.3
2000 q5 61.1
2005 q1 50
2005 q2 54.4
2005 q3 57.2
2005 q4 60
2005 q5 59.6
end

i need to draw graph like this

i used this code

graph dot cpm, over (quintile) over (year) asyvars  exclude0 yscale (range (25 65)) linetype (line) lines (lwidth (thin))

but my problem is about extremes lines! i want to hide or eliminate extremes lines but i dont know how

[Carole J. Wilson]

My inclination would be to use twoway graphs as they tend to be more flexible. If you play with this code, you may be able to get closer to your preferred graph:

bysort year: egen left=min(cpm)
bysort year: egen right=max(cpm)
twoway dot year cpm, ndots(0) xlab(,grid) xscale(range(25 65)) xlab(25(5)65) yscale(reverse) || rcap left right year  , hor legend(off) yscale(reverse)

[Javad Ebrahimzadeh]

I appreciate for your advice Carole but how i can differentiate the circles with different colors?
thank you.

[Carole J. Wilson]

I've changed it up a bit, but try this:

bysort year: egen left=min(cpm)
bysort year: egen right=max(cpm)
twoway rcap left right year  , hor legend(off) lwidth(medium) lcolor(gs10) ///
    || scatter year cpm if quintile=="q1", msize(large)  ///
    || scatter year cpm if quintile=="q2", msize(large)  ///
    || scatter year cpm if quintile=="q3", msize(large)  ///
    || scatter year cpm if quintile=="q4", msize(large)  ///
    || scatter year cpm if quintile=="q5", msize(large)  ///
        xscale(range(25 65)) xlab(25(5)65) xlab(,grid) ylab(,angle(horizontal))

[Javad Ebrahimzadeh]

that's amazing carole. it's great. thank you so so so much.

[Javad Ebrahimzadeh]

one more question carole, how i can add legend to introduce quintile circle colors?
thank you

[Carole J. Wilson]

twoway rcap left right year  , hor  lwidth(medium) lcolor(gs10) ///
    || scatter year cpm if quintile=="q1", msize(large)  ///
    || scatter year cpm if quintile=="q2", msize(large)  ///
    || scatter year cpm if quintile=="q3", msize(large)  ///
    || scatter year cpm if quintile=="q4", msize(large)  ///
    || scatter year cpm if quintile=="q5", msize(large)  ///
        xscale(range(25 65)) xlab(25(5)65) xlab(,grid) ylab(,angle(horizontal)) ///
        legend(order(2 "Quintile 1" 3 "Quintile 2" 4 "Quintile 3" ///
        5 "Quintile 4" 6 "Quintile 5") rows(1))

For more details and options for formatting the legend, see

help legend_options

[Nick Cox]

I would not use a dot plot here. To distinguish quintiles the markers need to be shown differently. Different colours (or markers) can only be arbitrary and the arbitrariness requires a legend and the legend obliges "back and forth" from the reader. In contrast one of my mottos is "lose the legend if you can" (or "kill the key"). Consider this alternative:

clear
input year str4 quintile cpm
1995 q1 28.2
1995 q2 39
1995 q3 47.1
1995 q4 52
1995 q5 57.4
2000 q1 42.7
2000 q2 50
2000 q3 54.3
2000 q4 58.3
2000 q5 61.1
2005 q1 50
2005 q2 54.4
2005 q3 57.2
2005 q4 60
2005 q5 59.6
end

gen pos = cond(q == "q4", 2, 3) 
set scheme s1color 
local lc lc(black)
line cpm year if quintile == "q1", `lc' || /// 
line cpm year if quintile == "q2", `lc' || /// 
line cpm year if quintile == "q3", `lc' || /// 
line cpm year if quintile == "q4", `lc' || /// 
line cpm year if quintile == "q5", `lc' || /// 
scatter cpm year if year == 2005,    ///
ms(none) mla(quintile) xsc(r(. 2005.5)) xtitle("") aspect(1) mlabvpos(pos) yla(, ang(h)) legend(off)

[Joseph Coveney]

I like the way that the lines are labeled, Nick. I'll have to remember that technique.

[Nick Cox]

Joseph: Thanks!

To spell it out, add marker labels to the last values (default clock position 3) and stretch the x axis accordingly. Sometimes, adding marker labels to the first values helps too: use a clock position of 9 in the first instance.

The idea is easy to understand, and certainly not original. The small Stata details are worth a short story and that is on my list for writing up in the Stata Journal in the near future.

[Javad Ebrahimzadeh]

thank you Ccarole! thank you Nick
also i add position (6) to legend to set legend below the graph.