Different colour for different time periods on same line graph

[Chris Rooney]

What I'd like to do this is this:

Plot ONE line graph of Total GDP v years but for each presidential period (i.e. 1994 - 1999, 2000 - 2008) use a different colour on the graph to indicate the different presidents. For example, the line colour would be green for 1994 - 1999, blue for 2000 - 2008 etc. Is this possible?

clear
input int Year long TotalGDPCurrentSApricesRm str9 President
1994 521395 "Mandela"
1995 563870 "Mandela"
1996 634611 "Mandela"
1997 703117 "Mandela"
1998 761658 "Mandela"
1999 834753 "Mandela"
2000 946324 "Mbeki"
2001 1046144 "Mbeki"
2002 1217265 "Mbeki"
2003 1325766 "Mbeki"
2004 1476623 "Mbeki"
2005 1639254 "Mbeki"
2006 1839400 "Mbeki"
2007 2109502 "Mbeki"
2008 2369063 "Mbeki"
2009 2507677 "Motlanthe"
2010 2748008 "Zuma"
2011 3023659 "Zuma"
2012 3253851 "Zuma"
2013 3539790 "Zuma"
2014 3807677 "Zuma"
2015 4049759 "Zuma"
2016 4345806 "Zuma"
2017 4529463 "Zuma"
end

[Chris Vecchio]

Here is one way to do it.

tsset Year
twoway (tsline TotalGDPCurrentSApricesRm if inrange(Year,1994,2000), lcolor(green)) (tsline TotalGDPCurrentSApricesRm if inrange(Year,2000,2008), lcolor(blue))

[Chris Rooney]

Thanks. Exactly what I hoped for!

Great.

[Nick Cox]

Wanting different colours means that you need different variables on the y axis.

separate is dedicated to this purpose. Apart from the help, see http://www.stata-journal.com/sjpdf.h...iclenum=gr0023

Here is some token code:

clear
input int Year long TotalGDPCurrentSApricesRm str9 President
1994 521395 "Mandela"
1995 563870 "Mandela"
1996 634611 "Mandela"
1997 703117 "Mandela"
1998 761658 "Mandela"
1999 834753 "Mandela"
2000 946324 "Mbeki"
2001 1046144 "Mbeki"
2002 1217265 "Mbeki"
2003 1325766 "Mbeki"
2004 1476623 "Mbeki"
2005 1639254 "Mbeki"
2006 1839400 "Mbeki"
2007 2109502 "Mbeki"
2008 2369063 "Mbeki"
2009 2507677 "Motlanthe"
2010 2748008 "Zuma"
2011 3023659 "Zuma"
2012 3253851 "Zuma"
2013 3539790 "Zuma"
2014 3807677 "Zuma"
2015 4049759 "Zuma"
2016 4345806 "Zuma"
2017 4529463 "Zuma"
end

gen Totalm = Total/1e6
separate Totalm, by(President) veryshortlabel
local yvars "`r(varlist)'"
twoway connect `yvars' Year, legend(col(1) pos(11) ring(0)) ytitle(sensible explanation) xtitle("") yla(, ang(h))

I used connect because Motlanthe does not show up on a line plot. A line from here to here is of zero length and as such hard to see. There are ways of fudging there, e.g. adding observations for 2008.5 and 2009.5.

Clearly different colours, markers, etc. are at choice. If this were my graph, I would lose the legend and put informative text with President names in the data region.