Time trends

[Marcus Malmsten]

I'm writing a thesis investigating how the level of public spending can dampen the fluctuations in GDP. I have data over the last 20 years on both GDP and public spending. I'm having trouble finding how I can turn my variable GDP into a variable that describes the deviation from GDP trend over time. I want to investigate if countries with a higher level of public spending have lower deviations in GDP from the GDP time trend, therefor I need a suitable variable for that. Thankful for any kind of thoughts

/Marcus

[Maarten Buis]

You need to first define the trend, in order to find deviations from a trend. For example, we can think of trend in additive terms (each year we become x euros/dollars/yens/... richer) or multiplicative terms (each year we become y percent richer). That is a choice you have to make. Then you need to think about how you define deviation, again either in absolute or relative terms.

After that it is just a matter of estimating the trends and computing the appropriate deviations. Below is an example:

// open example data: Penn World Tables
use "http://www.rug.nl/ggdc/docs/pwt90.dta", clear
encode country, gen(countrynum)

// prepare gdp per capita
gen gdppc = rgdpe/pop

// ================================== additive trend
// estimate trend for each country
reg gdppc c.year##i.countrynum

// store in a variable
// if e(sample) to avoid extrapolation
predict trend if e(sample)

// look at the resulting trends
sort countrynum year
twoway line trend year, connect(L)

// compute additive deviations
predict dev, resid


// ============================= multiplicative trend
// see e.g. http://blog.stata.com/2011/08/22/use-poisson-rather-than-regress-tell-a-friend/
poisson gdppc c.year##i.countrynum, vce(robust)
predict trend2 if e(sample)
twoway line trend2 year, connect(L)
gen dev2 = (gdppc - trend)/trend

[Mark Gertsen]

Alternatively to Maarten's suggestion, you might want to take a look at potential GDP as it could work out for your question. Potential GDP is the 'natural' GDP trend subject to certain parameters and you could see the difference between that and GDP. In other words, the 'Output gap' could be an alternative variable.

Additionally, public spending is generally seen as an automatic stabilizer in an economy. If GDP contracts or does not grow along trend (diverges more from potential GDP), these stabilizers might kick in.