Density Graph with threshold

[Federica Di Marcantonio]

Dears,

I would like to create a stata graph as the one below

The first step that is the density line is ok ( I only have 1 court), but I don't know how I could create the two "grey areas" on the same gr. I created two additional variable severe and stunted but I don't know how to get such a graph. Could you please give me some hints?
Thanks

Federica

[Maarten Buis]

sysuse nlsw88, clear
twoway scatteri 0 0 .15 0 .15  5 0  5,      ///
                recast(area) color(gs10) || /// first shaded area
       scatteri 0 5 .15 5 .15 10 0 10,      ///
                recast(area) color(gs8)  || /// second shaded area
       scatteri .15 2.5 (12) "very poor"    ///
                .15 7.5 (12) "poor",        /// labels on top
                 msymbol(i)              || ///
       kdensity wage, lstyle(p1)            /// density graph
                legend(off)                 ///
                yscale(range(0 .155))

[Michael McCulloch]

Hello Maarten, nice to see your comment. (You helped me a lot during my dissertation work.)

How could the above graph be altered to achieve Federica's posted example of a two-sample comparison of kdensity, where each of two values of var_x has its own line within the same graph?

Below is code of how I'd like the -at()- option to work in comparing wage at age==34 | age==44, but obviously it doesn't.

       kdensity wage, at(age==34 | age==44) lstyle(p1)            /// density graph
           legend(off)                 ///
           yscale(range(0 .155))

And this code does work but combines the two levels of age into the same kdensity plot line of wage.

kdensity wage if age==34 | age==44, lstyle(p1)            /// density graph
           legend(off)                 ///
           yscale(range(0 .155))

[Oded Mcdossi]

Michael McCulloch You can use the twoway graph with the if qualifier once for age 34 and once for 44, something like:

use http://www.stata-press.com/data/r13/lifeexp, clear
twoway kdensity lexp if region==1|| kdensity lexp if region==2

[Michael McCulloch]

Brilliant, Oded, that produces precisely what I intended. Many thanks.