Drop variables if label is empty

[Peter Lustig]

Hi all,

unfortunately i am not that familiar with stata. so this is my problem: i would like to delete all variables in my data set which have an empty (variable) label.
this is how far i got:

foreach v of varlist * {
local x : variable label `v'
}

Is it possible to include sth like this:
drop `v' if `x'==""
unfortunately this doesn't work. does anyone know how to do this?

thanks and kind regards

[Nick Cox]

The idea is a good start but would need two fixes:

foreach v of varlist * {
       local x : variable label `v'
        if "`x'" == "" drop `v' 
}

Here is something which loops for you:

ds, not(varlabel)
drop `r(varlist)'

See also findname (SJ). The syntax is similar

findname, varlabel not 
drop `r(varlist)'

[Peter Lustig]

Thanks a lot! I will try your code as soon as i am back in the office.

[Nick Cox]

Copying and pasting led to your font being copied too. This should look clearer. (Please follow FAQ Advice on using CODE delimiters.)

foreach v of varlist * {
    local x : variable label `v'
    if "`x'" == "" drop `v'
}

Nevertheless, I recommend ds or findname. findname is in effect an update of ds, but ds is official and findname is user-written and must be installed. I think the update improves the syntax; it certainly adds more features for other problems.

[Peter Lustig]

Hi Nick, your code worked perfectly. Thanks a lot!