Extract numbers and strings

[Torje Os]

Hello, I am wondering if there is a way in Stata where you can extract both numbers and strings. I want to create a new variable that extracts everything that contains numbers and a "G". For example the new variable should contain 300G and 2x150G (see picture).

[Torje Os]

Here's the picture

[William Lisowski]

Here's your example data presented in the standard way recommended by the Statalist FAQ linked to from the top of the page, as well as from the Advice on Posting link on the page you used to create your post.

* Example generated by -dataex-. For more info, type help dataex
clear
input str32 text
"STORFE BIFFSTRIMLER 350G FOLKETS"
"BEEF BURGER 2X150G FOLKETS"      
end

Will the letter G always appear as the final character in the string to be extracted, as it does in these two examples? And will it always have a digit immediately before it, as it does in these two examples?

[Torje Os]

Yes, the letter G will always follow the numbers with no space inbetween.

[Hemanshu Kumar]

Perhaps this?

clear
input str32 text
"STORFE BIFFSTRIMLER 350G FOLKETS"
"BEEF BURGER 2X150G FOLKETS"      
end

gen wanted = ustrregexs(0) if ustrregexm(text,"(\b[a-zA-Z0-9]+G\b)")

which produces:

. list , noobs

  +-------------------------------------------+
  |                             text   wanted |
  |-------------------------------------------|
  | STORFE BIFFSTRIMLER 350G FOLKETS     350G |
  |       BEEF BURGER 2X150G FOLKETS   2X150G |
  +-------------------------------------------+

This assumes there will be only one such word in each string. Is that okay, or are there possibly multiple such words in each?

[William Lisowski]

An enhacement to post #5 based on the answers given in post #4.

clear
input str32 text
"STORFE BIFFSTRIMLER 350G FOLKETS"
"BEEF BURGER 2X150G FOLKETS"      
"BEEF STEAK BIG CHOP"
end

gen wanted1 = ustrregexs(0) if ustrregexm(text,"(\b[a-zA-Z0-9]+G\b)")
gen wanted2 = ustrregexs(0) if ustrregexm(text,"(\b[a-zA-Z0-9]+[0-9]G\b)")
list, clean

. list, clean

                                   text   wanted1   wanted2  
  1.   STORFE BIFFSTRIMLER 350G FOLKETS      350G      350G  
  2.         BEEF BURGER 2X150G FOLKETS    2X150G    2X150G  
  3.                BEEF STEAK BIG CHOP       BIG

[Hemanshu Kumar]

William Lisowski Thanks for fixing that issue!

But in the spirit of further refinement:

* Example generated by -dataex-. For more info, type help dataex
clear
input str32 text
"STORFE BIFFSTRIMLER 350G FOLKETS"
"BEEF BURGER 2X150G FOLKETS"      
"BEEF STEAK BIG CHOP"
"BEEF BURGER 2X150XG CHOP"
end

gen wanted1 = ustrregexs(0) if ustrregexm(text,"(\b[a-zA-Z0-9]+G\b)")
gen wanted2 = ustrregexs(0) if ustrregexm(text,"(\b[a-zA-Z0-9]+[0-9]G\b)")
gen wanted3 = ustrregexs(0) if ustrregexm(text,"(\b[0-9a-zA-Z]*[0-9]+[0-9a-zA-Z]*G\b)")

which produces:

. list, noobs

  +----------------------------------------------------------------+
  |                             text   wanted1   wanted2   wanted3 |
  |----------------------------------------------------------------|
  | STORFE BIFFSTRIMLER 350G FOLKETS      350G      350G      350G |
  |       BEEF BURGER 2X150G FOLKETS    2X150G    2X150G    2X150G |
  |              BEEF STEAK BIG CHOP       BIG                     |
  |         BEEF BURGER 2X150XG CHOP   2X150XG             2X150XG |
  +----------------------------------------------------------------+

Edit: ah, but perhaps this case is ruled out by the description in #4. If so, never mind. wanted2 is what you want!

[Torje Os]

Thank you both! Helped us a lot. In our case #6 was the perfect solution