Grouping a numeric string variable

[Ellinor Reven]

Hi,
I have a dataset of numeric diagnostic codes from the icd-9 system (string variable). These codes range from 290-319, some with decimals, for instance:

id icd9
1 290.1
2 311
3 311.12
4 312
5 312
6 319.9
7 319.44

I need to group this variable (icd9), and have been using this command:
gen icd9gr=.
replace icd9gr=1 if substr(icd9n,1,3)== "290"
replace icd9gr=1 if substr(icd9n,1,3)== "291"
replace icd9gr=1 if substr(icd9n,1,3)== "292"
and so on

However this did not detect any of the codes with decimals. I actually do not need the decimal-numbers, so I tried to first use this command:
replace icd9 = subinstr(icd9, ".", "",.)
Then repeated the gen-and replace-command above, however the output is still not correct (some of the codes are not included).
Then I tried the following: gen icd9n = substr(icd9,1,3), however some of the numbers then turns out with only to digits. For instance 300.40 (original value) -> 30040 (after "replace icd"-command above) -> 30 (after final command).

Hope this makes sense to someone.
Help is much appreciated.

[Andrew Musau]

If this is a numerical variable, consider using the ceiling() or floor() functions or the int() function.

help ceil()
help floor()
help int()

Values in the range 290-299, e.g., mapped to 290

di floor(290/10)*10
di floor(296/10)*10
di floor(299/10)*10

Res.:

. di floor(290/10)*10
290

.
. di floor(296/10)*10
290

.
. di floor(299/10)*10
290

* Example generated by -dataex-. For more info, type help dataex
clear
input byte id double icd9
1  290.1
2    311
3 311.12
4    312
5    312
6  319.9
7 319.44
end

gen wanted1= floor(icd9/10)*10==290
gen wanted2= int(icd9/10)==29

Res.:

. l, sep(0)

     +---------------------------------+
     | id     icd9   wanted1   wanted2 |
     |---------------------------------|
  1. |  1    290.1         1         1 |
  2. |  2      311         0         0 |
  3. |  3   311.12         0         0 |
  4. |  4      312         0         0 |
  5. |  5      312         0         0 |
  6. |  6    319.9         0         0 |
  7. |  7   319.44         0         0 |
     +---------------------------------+

ADDED IN EDIT:

I need to group this variable (icd9), and have been using this command:
gen icd9gr=.
replace icd9gr=1 if substr(icd9n,1,3)== "290"
replace icd9gr=1 if substr(icd9n,1,3)== "291"
replace icd9gr=1 if substr(icd9n,1,3)== "292"

The following suggests that you have a string variable. Either use destring and the above if you have all numerical values or

* Example generated by -dataex-. For more info, type help dataex
clear
input byte id str6 icd9
1 "290.1"
2 "311"  
3 "311.12"
4 "312"  
5 "312"  
6 "319.9"
7 "319.44"
end

g wanted = ustrregexm(icd9, "^[29][0-9]|^[29][0-9][\.]")

Res.:

. l, sep(0)

     +----------------------+
     | id     icd9   wanted |
     |----------------------|
  1. |  1    290.1        1 |
  2. |  2      311        0 |
  3. |  3   311.12        0 |
  4. |  4      312        0 |
  5. |  5      312        0 |
  6. |  6    319.9        0 |
  7. |  7   319.44        0 |
     +----------------------+

[Hemanshu Kumar]

Since you are (a) starting with a string variable that is readable as a number, and (b) not interested in the decimal part of your code, and (c) wanted to end up with a numeric variable, I think the advice boils down to:

destring icd9, gen(icd9_num)
gen wanted = int(icd9_num)
drop icd9_num

or more succinctly:

gen wanted = real(ustrregexs(0)) if ustrregexm(icd9,"^([0-9]+)")

both of which produce:

. list , noobs sep(0)

  +----------------------+
  | id     icd9   wanted |
  |----------------------|
  |  1    290.1      290 |
  |  2      311      311 |
  |  3   311.12      311 |
  |  4      312      312 |
  |  5      312      312 |
  |  6    319.9      319 |
  |  7   319.44      319 |
  +----------------------+