Use variable labels to label leafs in dendrogram instead of variable names

[Dimitriy V. Masterov]

Here's an example of some code:

use http://www.stata-press.com/data/r13/wclub, clear
matrix dissimilarity clubD = , variables Jaccard dissim(oneminus)
clustermat singlelink clubD, name(club) clear labelvar(question)
cluster dendrogram club, labels(question) xlabel(, angle(90) labsize(*.75)) title(Single-linkage clustering) ytitle(1 - Jaccard similarity, suffix)

This is the graph it produces:



Would it be possible to get Stata to use the variable labels instead of their names at the bottom? For instance, to have "enjoy bicycle riding Y/N" instead of bike?

[Roberto Ferrer]

How about:

clear all
set more off

use132 wclub, clear

describe

set obs `r(k)'

gen vnames = ""
gen vlabels = ""
local i = 1
foreach v of varlist _all {

    capture replace vnames = "`v'" in `i'
    capture replace vlabels = "`:variable label `v''" in `i'
    local i = `i' + 1
    
}

keep vnames vlabels
rename vnames question

tempfile text
save "`text'"

use132 wclub, clear

matrix dissimilarity clubD = , variables Jaccard dissim(oneminus)

clustermat singlelink clubD, name(club) clear labelvar(question)

merge 1:1 question using "`text'", assert(match) nogen

cluster dendrogram club, labels(vlabels) xlabel(, angle(90) labsize(*.75)) ///
    title(Single-linkage clustering) ytitle(1 - Jaccard similarity, suffix)

It can be made a bit shorter, but the idea is the same. Substitute out -use132 ...-, which is a personal command (based on -use13-, of course).

[Roberto Ferrer]

A slightly different version:

clear all
set more off

use132 wclub, clear

quietly describe
local rk = `r(k)'

set obs `rk'

unab allvars: _all
tokenize `allvars'

gen vnames = ""
gen vlabels = ""
forvalues i = 1/`rk' {
    
    replace vnames = "``i''" in `i'
    replace vlabels = "`:variable label ``i'''" in `i'

}

<snip>

[Dimitriy V. Masterov]

Thanks, Roberto! This works very nicely.